package flashx.textLayout.events.examples {
    import flash.display.Sprite;
    
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.conversion.ConversionType;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.edit.EditManager;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.events.DamageEvent;
    import flashx.textLayout.events.UpdateCompleteEvent;
    
    public class DamageEvent_example extends Sprite
    {
        private var textFlow:TextFlow;
        private var text:String = "Text example";
        
        // In this example, the DamageEvent is used to mark when the text in the TextFlow has been changed,
        // so that a simple binding can be implemented that is optimized so that the binding is only updated
        // when the text is updated.
        public function DamageEvent_example()
        {
            textFlow = TextConverter.importToFlow(text, TextConverter.PLAIN_TEXT_FORMAT);
            textFlow.flowComposer.addController(new ContainerController(this, 200, 200));
            textFlow.interactionManager = new EditManager();
            textFlow.flowComposer.updateAllControllers();
                                    
            textFlow.addEventListener(DamageEvent.DAMAGE, damageHandler);
            textFlow.addEventListener(UpdateCompleteEvent.UPDATE_COMPLETE, updateHandler);
            
            // ... user clicks on the TextFlow and starts typing ...
        }
        
        private function updateHandler(event:UpdateCompleteEvent):void
        {
            if (text == null)
                text = TextConverter.export(textFlow, TextConverter.PLAIN_TEXT_FORMAT, ConversionType.STRING_TYPE) as String;
            trace(text);        // result: same as what's in the TextFlow
        }
        
        private function damageHandler(event:DamageEvent):void
        {
            text = null;
        }
    }
}