Package	flashx.textLayout.elements
Class	public final class InlineGraphicElement
Inheritance	InlineGraphicElement FlowLeafElement FlowElement Object

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

The InlineGraphicElement class handles graphic objects that display inline in the text.

You can embed a graphic or any DisplayObject or specify a URl for the location of the graphic. The height and width properties of InlineGraphicElement control the actual size of the graphic to display. These values also control how much space to allocate for the graphic in the TextLine object that contains the graphic. The height and width properties each can be one of:

1. A number of pixels
2. A percent of the measured size of the image
3. The constant, "auto", which computes the size (Default value)

There are three properties, or accessors, pertaining to the width and height of a graphic:

• The width and height properties
• The measuredWidth and measuredHeight properties, which are the width or height of the graphic at load time
• The actualWidth and actualHeight properties, which are the actual display and compose width and height of the graphic as computed from width or height and measuredWidth or measuredHeight

The values of the actualWidth and actualHeight properties are always zero until the graphic is loaded.

If source is specified as a URI, the graphic is loaded asynchronously. If it's a DisplayObject, TextLayout uses the width and height at the time the graphic is set into the InlineGraphicElement object as measuredHeight and measuredWidth; its width and height are read immediately.

Notes: For graphics that are loaded asynchronously the user must listen for a StatusChangeEvent.INLINE_GRAPHIC_STATUS_CHANGE event on the TextFlow and call IFlowComposer.updateAllControllers() to have the graphic appear. The value of measuredWidth and measuredHeight for graphics that are in the process of loading is zero.

Some inline graphics are animations or videos that possibly have audio. They begin to run the first time they are composed after they finish loading. They don't stop running until the flowComposer on the TextFlow is set to null. At that time they are stopped and unloaded.

The following restrictions apply to InLineGraphicElement objects:

1. On export of TLFMarkup, source is converted to a string. If the graphic element is a class, the Text Layout Framework can't export it properly
.
2. When doing a copy/paste operation of an InlineGraphicElement, if source can't be used to create a new InLineGraphicElement, it won't be pasted. For example if source is a DisplayObject, or if the graphic is set directly, it can't be duplicated. Best results are obtained if the source is the class of an embedded graphic though that doesn't export/import.
3. InLineGraphicElement objects work in the factory (TextFlowTextLineFactory) only if the source is a class or if you explicitly set the graphic to a loaded graphic. InlineGraphic objects that require delayed loads generally do not show up.

View the examples

See also

---

package flashx.textLayout.elements.examples 
{    
    import flash.display.Sprite;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.elements.InlineGraphicElement;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.container.ContainerController;
    
    
    public class InlineGraphicElement_sourceExample extends Sprite
    {    
        public function InlineGraphicElement_sourceExample(){
            // create a container and a controller for it
            var container:Sprite = new Sprite();
            this.stage.addChild(container);
            // create the TextFlow, ParagraphElement, SpanElement, and InlineGraphicElement objects    
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var inlineGraphicElement:InlineGraphicElement = new InlineGraphicElement();
            var span:SpanElement = new SpanElement();
            // add the graphic
            inlineGraphicElement.source = drawRect();
            // add text to the spans, spans and graphic to paragraph        
            span.text = "Too much depends upon a ";
            span.fontSize = 48;
            p.addChild(span); 
            p.addChild(inlineGraphicElement);
            // add paragraph to text flow and update controller to display
            textFlow.addChild(p);
            var controller:ContainerController = new ContainerController(container, 400, 300 );
            textFlow.flowComposer.addController(controller);
            textFlow.flowComposer.updateAllControllers(); 
        }

        private function drawRect():Sprite
        {
            var redRect:Sprite = new Sprite();
            redRect.graphics.beginFill(0xff0000);    // red
            redRect.graphics.drawRect(0,0,30, 30);
            redRect.graphics.endFill();
            return redRect;
        }
    }
}

package flashx.textLayout.elements.examples 
{    
    import flash.display.Sprite;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.elements.InlineGraphicElement;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.container.ContainerController;
    
    
    public class InlineGraphicElementExample extends Sprite
    {    
        public function InlineGraphicElementExample(){
            // create a container and a controller for it
            var container:Sprite = new Sprite();
            this.stage.addChild(container);
            var controller:ContainerController = new ContainerController(container, 400, 200 );
            // create the TextFlow, ParagraphElement, SpanElement, and InlineGraphicElement objects    
            var textFlow:TextFlow = new TextFlow();
            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var span2:SpanElement = new SpanElement();
            var inlineGraphicElement:InlineGraphicElement = new InlineGraphicElement();
            // add the graphic
            inlineGraphicElement.source = drwCircle();
            // add text to the spans, spans and graphic to paragraph        
            span1.text = "You can draw a happy face here ";
            span2.text = " if you like."
            p.fontSize = 16;
            p.addChild(span1);
            p.addChild(inlineGraphicElement);
            p.addChild(span2); 
            // add paragraph to text flow and update controller to display
            textFlow.addChild(p);
            textFlow.flowComposer.addController(controller);
            textFlow.flowComposer.updateAllControllers(); 
                    
            // draw a yellow circle for the graphic element
        }
        private function drwCircle():Sprite
        {
            var yellowCircle:Sprite = new Sprite();
            yellowCircle.graphics.beginFill(0xFFFF33);    // yellow
            yellowCircle.graphics.drawCircle(10,12,10);
            yellowCircle.graphics.endFill();
            return yellowCircle;
        }
    }
}